[prev in list] [next in list] [prev in thread] [next in thread]
List: openembedded-core
Subject: [OE-core] [PATCH v2 1/9] barebox: add initial support
From: Enrico Jörns <ejo () pengutronix ! de>
Date: 2023-03-31 10:40:17
Message-ID: 20230331104025.1478393-2-ejo () pengutronix ! de
[Download RAW message or body]
From: Marco Felsch <m.felsch@pengutronix.de>
This adds the support for the barebox bootloader to oe-core. The recipe
is based on the recipe found in meta-ptx [1] with a few minor adaptions.
This basic support includes the bootloader and the target tools to
interact with the bootloader. The host tools support is not part of
this commit. This will be added later on as separate recipe.
[1] https://github.com/pengutronix/meta-ptx/tree/master/recipes-bsp/barebox
Signed-off-by: Marco Felsch <m.felsch@pengutronix.de>
Signed-off-by: Enrico Jorns <ejo@pengutronix.de>
---
meta/conf/distro/include/maintainers.inc | 1 +
meta/recipes-bsp/barebox/barebox.inc | 133 ++++++++++++++++++
meta/recipes-bsp/barebox/barebox_2023.03.0.bb | 3 +
3 files changed, 137 insertions(+)
create mode 100644 meta/recipes-bsp/barebox/barebox.inc
create mode 100644 meta/recipes-bsp/barebox/barebox_2023.03.0.bb
diff --git a/meta/conf/distro/include/maintainers.inc \
b/meta/conf/distro/include/maintainers.inc index 682ec2cfdf..86d5519489 100644
--- a/meta/conf/distro/include/maintainers.inc
+++ b/meta/conf/distro/include/maintainers.inc
@@ -54,6 +54,7 @@ RECIPE_MAINTAINER:pn-automake = "Robert Yang \
<liezhi.yang@windriver.com>" RECIPE_MAINTAINER:pn-avahi = "Yi Zhao \
<yi.zhao@windriver.com>" RECIPE_MAINTAINER:pn-babeltrace = "Alexander Kanavin \
<alex.kanavin@gmail.com>" RECIPE_MAINTAINER:pn-babeltrace2 = "Alexander Kanavin \
<alex.kanavin@gmail.com>" +RECIPE_MAINTAINER:pn-barebox = "Enrico Jörns \
<yocto@pengutronix.de>" RECIPE_MAINTAINER:pn-baremetal-helloworld = "Alejandro \
Hernandez <alejandro@enedino.org>" RECIPE_MAINTAINER:pn-base-files = "Anuj Mittal \
<anuj.mittal@intel.com>" RECIPE_MAINTAINER:pn-base-passwd = "Anuj Mittal \
<anuj.mittal@intel.com>"
diff --git a/meta/recipes-bsp/barebox/barebox.inc \
b/meta/recipes-bsp/barebox/barebox.inc new file mode 100644
index 0000000000..a6c790b84b
--- /dev/null
+++ b/meta/recipes-bsp/barebox/barebox.inc
@@ -0,0 +1,133 @@
+SUMMARY = "barebox is a bootloader designed for embedded systems. It runs on a \
variety of architectures including x86, ARM, MIPS, PowerPC and others." +HOMEPAGE = \
"https://barebox.org/" +SECTION = "bootloaders"
+PROVIDES = "virtual/bootloader"
+
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=f5125d13e000b9ca1f0d3364286c4192"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+require conf/image-uefi.conf
+
+inherit kernel-arch deploy cml1 pkgconfig
+
+# libusb1 is only required for usb tools like imx-usb-loader. These tools may
+# be enabled within the defconfig file so depend on it here to be more user
+# friendly (do not abort the build). The actual tools are provided by the
+# barebox-tools package.
+DEPENDS = "libusb1 bison-native flex-native"
+
+export KBUILD_BUILD_USER ?= "oe-user"
+export KBUILD_BUILD_HOST ?= "oe-host"
+
+SRC_URI = "https://barebox.org/download/barebox-${PV}.tar.bz2"
+
+S = "${WORKDIR}/barebox-${PV}"
+B = "${WORKDIR}/build"
+
+def get_layer_rev(path):
+ try:
+ rev, _ = bb.process.run("git describe --match='' --always --dirty --broken", \
cwd=path) + except bb.process.ExecutionError:
+ rev = ""
+ return rev.strip()
+
+BAREBOX_BUILDSYSTEM_VERSION[doc] = "Build system version to add to the barebox \
image. By default this is the git description of the containing layer." \
+BAREBOX_BUILDSYSTEM_VERSION ??= \
"${@get_layer_rev(os.path.dirname(d.getVar('FILE')))}" +
+BAREBOX_FIRMWARE_DIR[doc] = "Overwrite barebox' firmware blobs search directory \
(CONFIG_EXTRA_FIRMWARE_DIR) with this path, default ${B}/firmware" \
+BAREBOX_FIRMWARE_DIR ??= "${B}/firmware" +
+EXTRA_OEMAKE = " \
+ CROSS_COMPILE=${TARGET_PREFIX} -C ${S} O=${B} \
+ BUILDSYSTEM_VERSION=${BAREBOX_BUILDSYSTEM_VERSION} \
+ CONFIG_EXTRA_FIRMWARE_DIR=${BAREBOX_FIRMWARE_DIR} \
+"
+
+BAREBOX_CONFIG[doc] = "The barebox kconfig defconfig file. Not used if a file called \
defconfig is added to the SRC_URI." +BAREBOX_CONFIG ?= ""
+
+do_configure() {
+ if [ -e ${WORKDIR}/defconfig ]; then
+ cp ${WORKDIR}/defconfig ${B}/.config
+ else
+ if [ -n "${BAREBOX_CONFIG}" ]; then
+ oe_runmake ${BAREBOX_CONFIG}
+ else
+ bbfatal "No defconfig given. Either add file \
'file://defconfig' to SRC_URI or set BAREBOX_CONFIG" + fi
+ fi
+
+ ${S}/scripts/kconfig/merge_config.sh -m .config ${@" ".join(find_cfgs(d))}
+ cml1_do_configure
+}
+
+BAREBOX_ENV_DIR[doc] = "Overlay the barebox built-in environment with the \
environment provided by the BSP if specified." +BAREBOX_ENV_DIR ??= "${WORKDIR}/env/"
+
+do_compile () {
+ export userccflags="${TARGET_LDFLAGS}${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
+ unset LDFLAGS
+ unset CFLAGS
+ unset CPPFLAGS
+ unset CXXFLAGS
+ unset MACHINE
+
+ if [ -d ${BAREBOX_ENV_DIR} ]; then
+ BAREBOX_DEFAULT_ENV="$(grep ^CONFIG_DEFAULT_ENVIRONMENT_PATH .config \
| cut -d '=' -f 2 | tr -d '"')" + oe_runmake \
CONFIG_DEFAULT_ENVIRONMENT_PATH="\"${BAREBOX_DEFAULT_ENV} ${BAREBOX_ENV_DIR}\"" + \
else + oe_runmake
+ fi
+}
+
+BAREBOX_BINARY[doc] = "Specify the barebox binary to install. If not specified all \
barebox artifacts are installed." +BAREBOX_BINARY ??= "${@'barebox.efi' if \
d.getVar('EFI_PROVIDER') == 'barebox' else ''}" +BAREBOX_SUFFIX[doc] = "Specify the \
suffix for ${BAREBOX_IMAGE}." +BAREBOX_SUFFIX ??= "img"
+BAREBOX_IMAGE[doc] = "A unique barebox image name. Unused if ${BAREBOX_BINARY} is \
not set." +BAREBOX_IMAGE_DEFAULT ?= "${PN}-${MACHINE}-${PV}-${PR}.${BAREBOX_SUFFIX}"
+BAREBOX_IMAGE ?= "${@'${EFI_BOOT_IMAGE}' if d.getVar('EFI_PROVIDER') == 'barebox' \
else '${BAREBOX_IMAGE_DEFAULT}'}" +
+BAREBOX_INSTALL_PATH ?= "${@'${EFI_FILES_PATH}' if d.getVar('EFI_PROVIDER') == \
'barebox' else '/boot'}" +
+do_install () {
+ if [ -n "${BAREBOX_BINARY}" ]; then
+
+ BAREBOX_BIN=${B}/${BAREBOX_BINARY}
+ if [ ! -f "${BAREBOX_BIN}" ]; then
+ BAREBOX_BIN=${B}/images/${BAREBOX_BINARY}
+ fi
+ if [ ! -f "${BAREBOX_BIN}" ]; then
+ bbfatal "Failed to locate ${BAREBOX_BINARY}"
+ fi
+
+ install -D -m 644 ${BAREBOX_BIN} \
${D}${BAREBOX_INSTALL_PATH}/${BAREBOX_IMAGE} + ln -sf ${BAREBOX_IMAGE} \
${D}${BAREBOX_INSTALL_PATH}/${BAREBOX_BINARY} + else
+ install -d ${D}${BAREBOX_INSTALL_PATH}/
+ for image in $(cat ${B}/barebox-flash-images); do
+ install -m 644 ${B}/${image} ${D}${BAREBOX_INSTALL_PATH}/
+ done
+ fi
+}
+FILES:${PN} = "${BAREBOX_INSTALL_PATH}"
+
+do_deploy () {
+ if [ -n "${BAREBOX_BINARY}" ]; then
+
+ BAREBOX_BIN=${B}/${BAREBOX_BINARY}
+ if [ ! -f "${BAREBOX_BIN}" ]; then
+ BAREBOX_BIN=${B}/images/${BAREBOX_BINARY}
+ fi
+
+ install -D -m 644 ${BAREBOX_BIN} ${DEPLOYDIR}/${BAREBOX_IMAGE}
+ ln -sf ${BAREBOX_IMAGE} ${DEPLOYDIR}/${BAREBOX_BINARY}
+ else
+ for image in $(cat ${B}/barebox-flash-images); do
+ cp ${B}/${image} ${DEPLOYDIR}
+ done
+ fi
+}
+addtask deploy after do_compile
diff --git a/meta/recipes-bsp/barebox/barebox_2023.03.0.bb \
b/meta/recipes-bsp/barebox/barebox_2023.03.0.bb new file mode 100644
index 0000000000..860b68a95f
--- /dev/null
+++ b/meta/recipes-bsp/barebox/barebox_2023.03.0.bb
@@ -0,0 +1,3 @@
+require barebox.inc
+
+SRC_URI[sha256sum] = \
"d0f78a69ba240327247c8fd0e1d45287e4a0dff99ed847e9a696cc2da0cf388c"
--
2.39.2
-=-=-=-=-=-=-=-=-=-=-=-
Links: You receive all messages sent to this group.
View/Reply Online (#179426): https://lists.openembedded.org/g/openembedded-core/message/179426
Mute This Topic: https://lists.openembedded.org/mt/97970649/4454766
Group Owner: openembedded-core+owner@lists.openembedded.org
Unsubscribe: https://lists.openembedded.org/g/openembedded-core/unsub [openembedded-core@marc.info]
-=-=-=-=-=-=-=-=-=-=-=-
[prev in list] [next in list] [prev in thread] [next in thread]
Configure |
About |
News |
Add a list |
Sponsored by KoreLogic