[prev in list] [next in list] [prev in thread] [next in thread]
List: openembedded-core
Subject: [OE-core] [PATCH v2 2/9] barebox-tools: add initial barebox tools support
From: Enrico Jörns <ejo () pengutronix ! de>
Date: 2023-03-31 10:40:18
Message-ID: 20230331104025.1478393-3-ejo () pengutronix ! de
[Download RAW message or body]
From: Marco Felsch <m.felsch@pengutronix.de>
Add initial support to build the barebox tools for the host and the
target.
Signed-off-by: Marco Felsch <m.felsch@pengutronix.de>
Signed-off-by: Enrico Jorns <ejo@pengutronix.de>
---
meta/conf/distro/include/maintainers.inc | 1 +
.../barebox/barebox-tools_2023.03.0.bb | 56 +++++++++++++++++++
2 files changed, 57 insertions(+)
create mode 100644 meta/recipes-bsp/barebox/barebox-tools_2023.03.0.bb
diff --git a/meta/conf/distro/include/maintainers.inc \
b/meta/conf/distro/include/maintainers.inc index 86d5519489..1a0ba10d3b 100644
--- a/meta/conf/distro/include/maintainers.inc
+++ b/meta/conf/distro/include/maintainers.inc
@@ -55,6 +55,7 @@ RECIPE_MAINTAINER:pn-avahi = "Yi Zhao <yi.zhao@windriver.com>"
RECIPE_MAINTAINER:pn-babeltrace = "Alexander Kanavin <alex.kanavin@gmail.com>"
RECIPE_MAINTAINER:pn-babeltrace2 = "Alexander Kanavin <alex.kanavin@gmail.com>"
RECIPE_MAINTAINER:pn-barebox = "Enrico Jörns <yocto@pengutronix.de>"
+RECIPE_MAINTAINER:pn-barebox-tools = "Enrico Jörns <yocto@pengutronix.de>"
RECIPE_MAINTAINER:pn-baremetal-helloworld = "Alejandro Hernandez \
<alejandro@enedino.org>" RECIPE_MAINTAINER:pn-base-files = "Anuj Mittal \
<anuj.mittal@intel.com>" RECIPE_MAINTAINER:pn-base-passwd = "Anuj Mittal \
<anuj.mittal@intel.com>"
diff --git a/meta/recipes-bsp/barebox/barebox-tools_2023.03.0.bb \
b/meta/recipes-bsp/barebox/barebox-tools_2023.03.0.bb new file mode 100644
index 0000000000..9ab1b6303d
--- /dev/null
+++ b/meta/recipes-bsp/barebox/barebox-tools_2023.03.0.bb
@@ -0,0 +1,56 @@
+SUMMARY = "barebox bootloader tools"
+HOMEPAGE = "https://barebox.org/"
+
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=f5125d13e000b9ca1f0d3364286c4192"
+
+DEPENDS = "libusb1 bison-native flex-native"
+
+SRC_URI = "https://barebox.org/download/barebox-${PV}.tar.bz2"
+SRC_URI[sha256sum] = \
"d0f78a69ba240327247c8fd0e1d45287e4a0dff99ed847e9a696cc2da0cf388c" +
+S = "${WORKDIR}/barebox-${PV}"
+B = "${WORKDIR}/build"
+
+inherit pkgconfig
+
+EXTRA_OEMAKE = " \
+ ARCH=sandbox \
+ CROSS_COMPILE=${TARGET_PREFIX} -C ${S} O=${B} \
+ CROSS_PKG_CONFIG=pkg-config \
+ "
+
+do_compile:class-target () {
+ export userccflags="${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
+ export userldflags="${TARGET_LDFLAGS}${TOOLCHAIN_OPTIONS}"
+ oe_runmake targettools_defconfig
+ oe_runmake scripts
+}
+
+do_compile:class-native () {
+ oe_runmake hosttools_defconfig
+ oe_runmake scripts
+}
+
+BAREBOX_TOOLS = " \
+ bareboxenv \
+ bareboxcrc32 \
+ kernel-install \
+ bareboximd \
+ omap3-usb-loader \
+ omap4_usbboot \
+ imx/imx-usb-loader \
+ "
+
+BAREBOX_TOOLS_SUFFIX = ""
+BAREBOX_TOOLS_SUFFIX:class-target = "-target"
+
+do_install () {
+ install -d ${D}${bindir}
+
+ for tool in ${BAREBOX_TOOLS}; do
+ install -m 0755 scripts/${tool}${BAREBOX_TOOLS_SUFFIX} ${D}${bindir}/${tool##*/}
+ done
+}
+
+BBCLASSEXTEND = "native nativesdk"
--
2.39.2
-=-=-=-=-=-=-=-=-=-=-=-
Links: You receive all messages sent to this group.
View/Reply Online (#179424): https://lists.openembedded.org/g/openembedded-core/message/179424
Mute This Topic: https://lists.openembedded.org/mt/97970647/4454766
Group Owner: openembedded-core+owner@lists.openembedded.org
Unsubscribe: https://lists.openembedded.org/g/openembedded-core/unsub [openembedded-core@marc.info]
-=-=-=-=-=-=-=-=-=-=-=-
[prev in list] [next in list] [prev in thread] [next in thread]
Configure |
About |
News |
Add a list |
Sponsored by KoreLogic