[prev in list] [next in list] [prev in thread] [next in thread]
List: mumps-l
Subject: Re: Cache' benchmark ??
From: Alberto de Tisi <adetisi () trak ! it>
Date: 1999-03-31 7:49:59
[Download RAW message or body]
Hi,
this is a simple routine that writes and reads three times a (big) global
with about
10000 subscripts at the first level, 20 at the second level and 5 at the
third level filling each level with three different strings randomly.
I've run the routine on my server at office and i've inserted in it the
time (in milliseconds) that takes to complete the test as the referring
time for the Benchmark.
I've wrote this routine since i received the e-mail about the speed of
Cachè over Linux and i realized that there's nothing to really compare two
systems.
Please finde attached to this mail the zip file containg the .INT code of
that routine.
This file was created with the ^%RO utility from Cachè version 2.1.7 B30
and it should be imported
using the ^%RI utility.
You can also open the file with a text editor and cut and past it into your
M editor.
Let me know.
Ciao.
Alberto.
At 16.56 30/03/1999 -0500, you wrote:
>Hi Alberto,
>
>Yes I would be interested.
>
>Thanks,
>
>Bain
>
>At 01:26 PM 3/30/99 , you wrote:
>>
>> Anybody intersted running an own developed Benchmark routine for Cachè ??
>> If so contact me and i will send it to you in a few.
>>
>> Ciao.
>> Alberto
>>
>>
>>
>>
>>
>> Alberto de Tisi
>> Product Specialist
>> Trak Systems Italia S.r.l.
>> v. V.Veneto,8 Centro Comm. Sibrium DS1
>> 21013 Gallarate (VA) - Italy -
["zbench.ro" (text/plain)]
Cache for Windows NT^INT^Benchmark Routine to test Cachè performances
%RO on 31 Mar 1999 9:46 AM
ZBENCH.INT.1.57798,34884.
ZBENCH ; Benchmark routine writing and reading a global
n
S $ZT="ERRM"
k TESTS s LOOPS=3
w !!," THIS BENCHMARK TAKES AT LEAST 25600 OF DATA BLOCKS"
W !," BEFOR YOU CONTINUE PLEASE CHECK USING ^%FREECNT THAT IN YOUR DIRECTORY"
W !," THERE'S ENOUGH FREE BLOCKS (NOT ONLY EXPANSIONS AVILABLE!)"
W !," IF YOUR DATASET SHOULD EXPAND ITSELF TO REACH THIS AMOUNT OF DATA BLOCKS YOU"
W !," WILL HAVE TO RUN THIS BENCHMARK TWICE, THE FIRST ONE TO ENLARGE THE DATASET"
W !," AND THE SECOND ONE TO DO THE TEST."
W !!," DO NOT RUN THIS BECNHMARK ON A LIVE NAMESPACE. USE THE 'USER' NAMESPACE"
W !!," RUN THIS BECNHMARK ONLY WITH NO USER CONNECTED,IF YOU WANT TO GET REAL VALUES"
W !!," IF YOU ARE READY TO START THE BENCHMARK PRESS Y :" R ANSW
I ANSW'="Y",ANSW'="y" Q
w !!!,"Benchmark Started for "_LOOPS_" loops..."
f n=1:1:LOOPS d TEST
; Mean Values
s (TOR,TOR1,TOR2)=0
for n=1:1:LOOPS d
.s line=$g(TESTS(n))
.s TOR=TOR+$p(line,"^",1)
.s TOR1=TOR1+$p(line,"^",2)
.s TOR2=TOR2+$p(line,"^",3)
s TOR=TOR\LOOPS,TOR1=TOR1\LOOPS,TOR2=TOR2\LOOPS
;---------
w !!!,"Benchmark Completed !",!
s SEC=TOR1\1000,CENT=TOR1-((TOR1\1000)*1000)
w !," "_ENTRY_" Entries written in "_SEC_"."_CENT_" seconds."
s SEC=TOR2\1000,CENT=TOR2-((TOR2\1000)*1000)
w !," "_ENTRY_" Entries readed in "_SEC_"."_CENT_" seconds."
s SEC=TOR\1000,CENT=TOR-((TOR\1000)*1000)
w !," Total Time: "_SEC_"."_CENT_" seconds. ("_TOR_" ms.)",!
;----------
i TOR<REFERRING d
.s DIFF=REFERRING-TOR,PERC=$FN((DIFF*100)/REFERRING,",",2)
.w !," Your System is performing "_PERC_"% faster than the Referring System"
i TOR>REFERRING d
.s DIFF=TOR-REFERRING,PERC=$FN((DIFF*100)/REFERRING,",",2)
.w !," Your System is performing "_PERC_"% slower than the Referring System"
i TOR=REFERRING d
.w !," Your System is performing exactly like the Referring System"
w !!," Referring System: PC Pentium II-333Mhz"
w !," 80M RAM 12G EIDE Disks"
w !," WindowsNT Server 4.0(Sp3)"
w !," Cache' 2.1.7 B30",!!
END k ^ZBt
q
TEST k ^ZBt s ENTRY=0,RENTRY=0,REFERRING=106670
s C1=10000,C2=20,C3=5,MARK=100 ; Sets for lenght and hash mark printing interval
s T1=$ZTIMESTAMP,SECT1=$p($p(T1,",",2),".",1),CENT1=$p($p(T1,",",2),".",2),TR1=SECT1*1000+CENT1
s $p(T1,",",1)=$ZD(T1,3),$p(T1,",",2)=$ZT($p(T1,",",2))_"."_$p($p(T1,",",2),".",2)
w !!,?30,"LOOP NUMBER "_n
w !!,?20,"- TimeStamp: "_T1_" -"
w !,?30," ....now writing the global..."
s v(0)="sakfhkjsahdkfasmklop"
s v(1)="sjdgjksgfkjsgkjfgskjgfkjdgfkjdgkjlopiuyt"
s v(2)="49836495873645woityieyiewyiewuytwiewutywiuyfshsdfhsdhsdhsdhsdhklouy678987654321"
f i=1:1:C1 d
.;i (i#MARK)=0 w "."
.s ^ZBt(i)=v($R(3)),ENTRY=$ZINCREMENT(ENTRY)
.f k=1:1:C2 d
..s ^ZBt(i,k)=v($R(3)),ENTRY=$ZINCREMENT(ENTRY)
..f j=1:1:C3 d
...s ^ZBt(i,k,j)=v($R(3)),ENTRY=$ZINCREMENT(ENTRY)
s T2=$ZTIMESTAMP,SECT2=$p($p(T2,",",2),".",1),CENT2=$p($p(T2,",",2),".",2),TR2=SECT2*1000+CENT2
s $p(T2,",",1)=$ZD(T2,3),$p(T2,",",2)=$ZT($p(T2,",",2))_"."_$p($p(T2,",",2),".",2)
w !,?20,"- TimeStamp: "_T2_" -"
w !,?30," ....now reading the global..."
s s1="" f s s1=$o(^ZBt(s1)) q:s1="" d
.s data=$g(^ZBt(s1)),RENTRY=$ZINCREMENT(RENTRY) ;i (RENTRY#MARK)=0 w "."
.s s2="" f s s2=$o(^ZBt(s1,s2)) q:s2="" d
..s data=$g(^ZBt(s1,s2))
..s s3="" f s s3=$o(^ZBt(s1,s2,s3)) q:s3="" d
...s data=$g(^ZBt(s1,s2,s3))
s T3=$ZTIMESTAMP,SECT3=$p($p(T3,",",2),".",1),CENT3=$p($p(T3,",",2),".",2),TR3=SECT3*1000+CENT3
s $p(T3,",",1)=$ZD(T3,3),$p(T3,",",2)=$ZT($p(T3,",",2))_"."_$p($p(T3,",",2),".",2)
w !,?30,"LOOP COMPLETED !"
w !,?20,"- TimeStamp: "_T3_" -",!
s TOR1=TR2-TR1,TOR2=TR3-TR2,TOR=TR3-TR1,TESTS(n)=TOR_"^"_TOR1_"^"_TOR2
q
ERRM
w !!,?10,"M-ERROR IN ^ZBENCH :"_$ZE
W !,?10,"NOW STOPPING THE BENCHMARK AND REMOVING GLOBALS..."
g END
[Attachment #4 (text/html)]
<html>
<br>
<br>
<br>
<b><i> <font face="Bookman Old Style, Bookman" size=4>Alberto de
Tisi<br>
</font></i>Product Specialist<br>
<i>Trak Systems Italia S.r.l.<br>
v. V.Veneto,8 Centro Comm. Sibrium DS1<br>
21013 Gallarate (VA) - Italy -</b></i></html>
[prev in list] [next in list] [prev in thread] [next in thread]
Configure |
About |
News |
Add a list |
Sponsored by KoreLogic