[prev in list] [next in list] [prev in thread] [next in thread] 

List:       gentoo-commits
Subject:    [gentoo-commits] gentoo-x86 commit in dev-python/graphy: graphy-1.0-r1.ebuild ChangeLog
From:       "Michal Gorny (mgorny)" <mgorny () gentoo ! org>
Date:       2013-07-31 22:58:21
Message-ID: 20130731225821.3E6132171C () flycatcher ! gentoo ! org
[Download RAW message or body]

mgorny      13/07/31 22:58:21

  Modified:             ChangeLog
  Added:                graphy-1.0-r1.ebuild
  Log:
  Migrate to distutils-r1, bug #479292.
  
  (Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key \
9627F456F9DA7643!)

Revision  Changes    Path
1.4                  dev-python/graphy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graphy/ChangeLog?rev=1.4&view=markup
                
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graphy/ChangeLog?rev=1.4&content-type=text/plain
                
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graphy/ChangeLog?r1=1.3&r2=1.4


Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/graphy/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	16 Jun 2012 07:43:36 -0000	1.3
+++ ChangeLog	31 Jul 2013 22:58:21 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/graphy
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/graphy/ChangeLog,v 1.3 2012/06/16 \
07:43:36 pacho Exp $ +# Copyright 1999-2013 Gentoo Foundation; Distributed under the \
GPL v2 +# $Header: /var/cvsroot/gentoo-x86/dev-python/graphy/ChangeLog,v 1.4 \
2013/07/31 22:58:21 mgorny Exp $ +
+*graphy-1.0-r1 (31 Jul 2013)
+
+  31 Jul 2013; Michał Górny <mgorny@gentoo.org> +graphy-1.0-r1.ebuild:
+  Migrate to distutils-r1, bug #479292.
 
   16 Jun 2012; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Drop maintainer as he is not able to maintain this anymore.
@@ -13,4 +18,3 @@
   24 Dec 2009; Mounir Lamouri <volkmar@gentoo.org> +graphy-1.0.ebuild,
   +metadata.xml:
   Initial commit
-



1.1                  dev-python/graphy/graphy-1.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graphy/graphy-1.0-r1.ebuild?rev=1.1&view=markup
                
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/graphy/graphy-1.0-r1.ebuild?rev=1.1&content-type=text/plain


Index: graphy-1.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/graphy/graphy-1.0-r1.ebuild,v 1.1 \
2013/07/31 22:58:21 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )

inherit distutils-r1

MY_P=${PN}_${PV}

DESCRIPTION="Simple Chart Library for Python"
HOMEPAGE="http://code.google.com/p/graphy/"
SRC_URI="http://${PN}.googlecode.com/files/${MY_P}.tar.bz2"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="examples"

S=${WORKDIR}/${MY_P}

python_prepare_all() {
	# drop Python version (2.4) from shebangs
	find -name '*.py' -exec sed -i -e '1s:python2\.4:python:' {} + \
		|| die "shebang sed failed"
	# clean up
	find graphy/ -name '*.pyc' -delete || die
	find graphy/ -name '.svn' -exec rm -rf {} + || die

	distutils-r1_python_prepare_all
}

python_compile() {
	:
}

python_test() {
	local PYTHONPATH
	mkdir -p "${BUILD_DIR}"/lib || die
	cp -r graphy "${BUILD_DIR}"/lib/ || die
	"${PYTHON}" "${BUILD_DIR}"/lib/graphy/all_tests.py \
		|| die "Tests fail with ${EPYTHON}"
}

python_install() {
	python_domodule graphy
}

python_install_all() {
	use examples && local EXAMPLES=( examples/. )

	distutils-r1_python_install_all
}


[prev in list] [next in list] [prev in thread] [next in thread]