[prev in list] [next in list] [prev in thread] [next in thread]
List: cygwin-xfree
Subject: RE: XWin 6.8.99.901-4-Problems with fonts and clipboard module - cygcheck.out (0/1)
From: "Phil Betts" <Phil.Betts () ascribe ! com>
Date: 2007-05-11 14:23:51
Message-ID: 2D9E96311DCA4C48BF185EA6928BC7BB01BC6D0C () asc-mail ! int ! ascribe ! com
[Download RAW message or body]
Robert Neville wrote on Thursday, May 10, 2007 10:07 PM::
> After reinstalling X and all fonts, I mounted the font path and still
> receive this error.
>
> Could not init font path element /usr/X11R6/lib/X11/fonts/CID/,
> removing from list!
This is not an error, it is just a warning. If you had searched the
archive you would have known this. Everyone will get this in their
log unless they've explicitly installed fonts into the CID directory.
Your problem has nothing to do with fonts.
> winProcSetSelectionOwner - Clipboard not yet started, aborting.
> winProcSetSelectionOwner - Clipboard not yet started, aborting.
> winClipboardProc - winClipboardFlushWindowsMessageQueue trapped
> WM_QUIT message, exiting main loop. winClipboardProc - XDestroyWindow
> succeeded.
>
> winClipboardIOErrorHandler!
This appears to be your problem. My guess is that either:
a) something is trying to communicate with the X clipboard before
it has finished its initialisation. If this is the case, you might
find my version of startxwin.bat useful (attached, just save & rename
it). This waits for a key line to appear in the XWin log file before
trying to launch any client programs.
b) you have some firewall/antivirus/other software that is interfering
with the communication with the X clipboard. The advice is generally
to uninstall such software. Just disabling them still leaves them
hooked into the system. Dave Korn has been compiling a list of the
known offenders in the cygwin-talk thread "The Big List of Dodgy Apps".
Search the mail archives to see if you have any of the mentioned
programs.
If none of the above works, you could always try the obsolete xwinclip,
which is a standalone clipboard handler. To install it via cygwin
setup, you need to uncheck the "hide obsolete and administrative
packages" option. To use it, you need to remove the -clipboard option
from the XWin command line, start the X server, then enter the command
"run xwinclip". This is not particularly reliable, and IIRC some key
changes regarding data conversion are missing from it, but at least
when it crashes, it doesn't cause X to die too. Note that because
this package is obsolete (and has been for quite some time), you
cannot expect any support for it.
HTH,
Phil
["startxwin.txt" (text/plain)]
@echo off
SET DISNO=0
SET DISPLAY=127.0.0.1:%DISNO%.0
REM
REM The path in the CYGWIN_ROOT environment variable assignment assume
REM that Cygwin is installed in a directory called 'cygwin' in the root
REM directory of the current drive. You will only need to modify
REM CYGWIN_ROOT if you have installed Cygwin in another directory. For
REM example, if you installed Cygwin in \foo\bar\baz\cygwin, you will need
REM to change \cygwin to \foo\bar\baz\cygwin.
REM
REM This batch file will almost always be run from the same drive (and
REM directory) as the drive that contains Cygwin/X, therefore you will
REM not need to add a drive letter to CYGWIN_ROOT. For example, you do
REM not need to change \cygwin to c:\cygwin if you are running this
REM batch file from the C drive.
REM
SET CYGWIN_ROOT=C:\cygwin
SET CYGWIN_TMP=C:\cygwin\tmp
SET CYGWIN_USR=C:\cygwin\usr
SET PATH=%CYGWIN_USR%\X11R6\bin;%CYGWIN_ROOT%\bin;%CYGWIN_USR%\local\bin;%PATH%
SET XAPPLRESDIR=/usr/X11R6/lib/X11/app-defaults
SET XCMSDB=/usr/X11R6/lib/X11/Xcms.txt
SET XKEYSYMDB=/usr/X11R6/lib/X11/XKeysymDB
SET XNLSPATH=/usr/X11R6/lib/X11/locale
REM
REM Cleanup after last run.
REM
if not exist %CYGWIN_TMP%\.X11-unix\X%DISNO% goto CLEANUP-FINISH
attrib -s %CYGWIN_TMP%\.X11-unix\X%DISNO%
del %CYGWIN_TMP%\.X11-unix\X%DISNO%
:CLEANUP-FINISH
if exist %CYGWIN_TMP%\.X11-unix rmdir %CYGWIN_TMP%\.X11-unix
REM
REM The error "Fatal server error: could not open default font 'fixed'" is
REM caused by using a DOS mode mount for the mount that the Cygwin/X
REM fonts are accessed through. See the Cygwin/X FAQ for more
REM information:
REM http://x.cygwin.com/docs/faq/cygwin-x-faq.html#q-error-font-eof
REM
if "%OS%" == "Windows_NT" goto OS_NT
REM Windows 95/98/Me
echo startxwin.bat - Starting on Windows 95/98/Me
goto STARTUP
:OS_NT
REM Windows NT/2000/XP/2003
echo startxwin.bat - Starting on Windows NT/2000/XP/2003
:STARTUP
REM Brief descriptions of XWin-specific options:
REM
REM -engine engine_type_id
REM Override the server's automatically selected engine type:
REM 1 - Shadow GDI
REM 2 - Shadow DirectDraw
REM 4 - Shadow DirectDraw4 Non-Locking
REM 16 - Native GDI - experimental
REM -screen scr_num [width height]
REM Enable screen scr_num and optionally specify a width and
REM height for that screen.
REM Most importantly, any parameters specified before the first -screen
REM parameter apply to all screens. Any options after the first -screen
REM parameter apply only to the screen that precedes the parameter.
REM Example:
REM XWin -fullscreen -screen 0 -screen 1 -depth 8 -screen 2
REM All screens will be fullscreen, but screen 2 will be depth 8, while
REM screens 0 and 1 will be the default depth (whatever depth Windows
REM is currently running at).
REM -multiwindow
REM Start an integrated Windows-based window manager. Not to be used
REM with -rootless nor -fullscreen.
REM -rootless
REM Use a transparent root window with an external window manager
REM (such as twm). Not to be used with -multiwindow nor
REM with -fullscreen.
REM -fullscreen
REM Use a window as large as possible on the primary monitor.
REM -multiplemonitors
REM Create a root window that covers all monitors on a
REM system with multiple monitors.
REM -clipboard
REM Enable the integrated version of xwinclip. Do not use in
REM conjunction with the xwinclip program.
REM -depth bits_per_pixel
REM Specify the screen depth to run at (in bits per pixel) using a
REM DirectDraw-based engine in conjunction with the -fullscreen
REM option, ignored if the -fullscreen option is not specified.
REM By default, you will be using a DirectDraw based engine on any
REM system that supports it.
REM -clipupdates num_boxes
REM Use a clipping region to constrain shadow update blits to
REM the updated region when num_boxes, or more, are in the
REM updated region. Currently supported only by `-engine 1'.
REM -emulatepseudo
REM Create a depth 8 PseudoColor visual when running in
REM depths 15, 16, 24, or 32, collectively known as TrueColor
REM depths. The PseudoColor visual does not have correct colors,
REM and it may crash, but it at least allows you to run your
REM application in TrueColor modes.
REM -unixkill
REM Trap Ctrl+Alt+Backspace as a server shutdown key combination.
REM -nounixkill
REM Disable Ctrl+Alt+Backspace as a server shutdown key combination (default).
REM Example:
REM XWin -unixkill -screen 0 -screen 1 -screen 2 -nounixkill
REM Screens 0 and 1 will allow Ctrl+Alt+Backspace, but screen 2 will not.
REM -winkill
REM Trap Alt+F4 as a server shutdown key combination (default).
REM -nowinkill
REM Disable Alt+F4 as a server shutdown key combination.
REM -scrollbars
REM Enable resizing of the server display window. Do not use in conjunction
REM with -multiwindow nor with -rootless.
REM -nodecoration
REM Draw the server root window without a title bar or border.
REM Do not use with -mutliwindow nor with -rootless.
REM -lesspointer
REM Hide the Windows mouse cursor anytime it is over any part of the
REM window, even if Cygwin/X is not the window with the focus.
REM -refresh rate_in_Hz
REM Specify a refresh rate to use when used with the -fullscreen option.
REM -trayicon
REM Enable the tray icon (default).
REM -notrayicon
REM Disable the tray icon.
REM Example:
REM XWin -notrayicon -screen 0 -screen 1 -screen 2 -trayicon
REM Screens 0 and 1 will not have tray icons, but screen 2 will.
REM -emulate3buttons [timeout]
REM Emulate 3 button mouse with an optional timeout in milliseconds.
REM -xf86config
REM Specify an XF86Config-style configuration file.
REM -keyboard
REM Specify a keyboard device from the configuration file.
REM
REM Startup the programs
REM
REM Startup the X Server with the integrated Windows-based window manager.
REM WARNING: Do not use 'xwinclip' in conjunction with the ``-clipboard''
REM command-line parameter for XWin. Doing so would start two clipboard
REM managers, which is never supposed to happen.
set CYGWIN=server
run XWin :%DISNO% -multiwindow -lesspointer -nowinkill -nounixkill -clipboard -silent-dup-error
echo Started XWin for display %DISPLAY%
REM Wait until fully started before running xhost/xmodmap
REM After 10 seconds finishes anyway
SET XWIN_LOG=%CYGWIN_TMP%\XWin.log
SET LASTLINE="winInitMultiWindowWM - XOpenDisplay () returned and successfully opened the display."
set /a COUNT=0
:WAITFORLOG
echo ...Waiting for X log file...
sleep 1
set /a COUNT+=1
if not exist %XWIN_LOG% goto WAITFORLOG
if %COUNT% GEQ 10 goto WARNFINISHOFF
:WAITFORIT
echo ...Waiting for X to initialise...
set /a COUNT=0
sleep 1
set /a COUNT+=1
if %COUNT% GEQ 30 goto WARNFINISHOFF
C:\WINDOWS\system32\find.exe %LASTLINE% < %XWIN_LOG% > nul
if errorlevel 1 goto WAITFORIT
echo "X started OK"
goto FINISHOFF
:WARNFINISHOFF
echo "WARNING: X doesn't appear to have started cleanly"
sleep 5
:FINISHOFF
REM remove the following two lines if you don't have a .Xmodmap
run xmodmap %HOME%\.Xmodmap
echo "xmodmap run"
REM Startup an xterm, using bash as the shell.
REM run xterm -sl 1000 -sb -rightbar -ms red -fg yellow -bg black -e /usr/bin/bash -l
REM
REM Startup the twm window manager.
REM WARNING: Do not use an external window manager in conjunction with
REM the ``-multiwindow'' command-line parameter for XWin. Doing so
REM would start two window managers, which is never supposed to happen.
REM
REM run twm
REM Set a background color. Only needed when not using -multwindow for XWin.
REM run xsetroot -solid aquamarine4
REM Now set pointer closest to Windows one + BSOD for root window
xsetroot -cursor_name left_ptr -fg white -bg black -solid steelblue
REM remove the following lines if you don't have fonts in these directories
xset fp+ /usr/X11R6/lib/X11/fonts/decwin/100dpi
xset fp+ /usr/X11R6/lib/X11/fonts/decwin/75dpi
REM only enable the following line if -clipboard is NOT on the XWin command line
REM run xwinclip
echo XWin ready to use!
sleep 3
--
Unsubscribe info: http://cygwin.com/ml/#unsubscribe-simple
Problem reports: http://cygwin.com/problems.html
Documentation: http://x.cygwin.com/docs/
FAQ: http://x.cygwin.com/docs/faq/
[prev in list] [next in list] [prev in thread] [next in thread]
Configure |
About |
News |
Add a list |
Sponsored by KoreLogic