'svn commit: r1871998 - in /apr/apr/trunk: Makefile.in build/apr_rules.mk.in build/ax_prog_cc_for_bui'

[prev in list] [next in list] [prev in thread] [next in thread] 

List:       apr-cvs
Subject:    svn commit: r1871998 - in /apr/apr/trunk: Makefile.in build/apr_rules.mk.in build/ax_prog_cc_for_bui
From:       minfrin () apache ! org
Date:       2019-12-26 11:04:59
Message-ID: 20191226110459.2B21517A010 () svn01-us-east ! apache ! org
[Download RAW message or body]

Author: minfrin
Date: Thu Dec 26 11:04:58 2019
New Revision: 1871998

URL: http://svn.apache.org/viewvc?rev=1871998&view=rev
Log:
Submitted by: Hongxu Jia <hongxu.jia@windriver.com>
https://patch-diff.githubusercontent.com/raw/apache/apr/pull/8.patch

While cross-compiling, the tools/gen_test_char could not
be executed at build time, use AX_PROG_CC_FOR_BUILD to
build native tools/gen_test_char

Support explicit libtool by variable assigning before buildcheck.sh,
it is helpful for cross-compiling (such as libtool=aarch64-linux-libtool)


Added:
    apr/apr/trunk/build/ax_prog_cc_for_build.m4
Modified:
    apr/apr/trunk/Makefile.in
    apr/apr/trunk/build/apr_rules.mk.in
    apr/apr/trunk/build/buildcheck.sh
    apr/apr/trunk/configure.in

Modified: apr/apr/trunk/Makefile.in
URL: http://svn.apache.org/viewvc/apr/apr/trunk/Makefile.in?rev=1871998&r1=1871997&r2=1871998&view=diff
 ==============================================================================
--- apr/apr/trunk/Makefile.in (original)
+++ apr/apr/trunk/Makefile.in Thu Dec 26 11:04:58 2019
@@ -53,7 +53,7 @@ LT_VERSION = @LT_VERSION@
 
 CLEAN_TARGETS = apr-config.out apr.exp exports.c export_vars.c .make.dirs \
 	build/apr_rules.out tools/gen_test_char@EXEEXT@ \
-	tools/gen_test_char.o tools/gen_test_char.lo \
+	tools/gen_test_char.o \
 	include/private/apr_escape_test_char.h
 DISTCLEAN_TARGETS = config.cache config.log config.status \
 	include/apr.h include/arch/unix/apr_private.h \
@@ -163,13 +163,9 @@ check: $(TARGET_LIB)
 etags:
 	etags `find . -name '*.[ch]'`
 
-OBJECTS_gen_test_char = tools/gen_test_char.lo $(LOCAL_LIBS)
-tools/gen_test_char.lo: tools/gen_test_char.c
+tools/gen_test_char@EXEEXT@: tools/gen_test_char.c
 	$(APR_MKDIR) tools
-	$(LT_COMPILE)
-
-tools/gen_test_char@EXEEXT@: $(OBJECTS_gen_test_char)
-	$(LINK_PROG) $(OBJECTS_gen_test_char) $(ALL_LIBS)
+	$(CC_FOR_BUILD) $(CFLAGS_FOR_BUILD) $< -o $@
 
 include/private/apr_escape_test_char.h: tools/gen_test_char@EXEEXT@
 	$(APR_MKDIR) include/private

Modified: apr/apr/trunk/build/apr_rules.mk.in
URL: http://svn.apache.org/viewvc/apr/apr/trunk/build/apr_rules.mk.in?rev=1871998&r1=1871997&r2=1871998&view=diff
 ==============================================================================
--- apr/apr/trunk/build/apr_rules.mk.in (original)
+++ apr/apr/trunk/build/apr_rules.mk.in Thu Dec 26 11:04:58 2019
@@ -32,6 +32,7 @@ APR_MAJOR_VERSION=@APR_MAJOR_VERSION@
 APR_DOTTED_VERSION=@APR_DOTTED_VERSION@
 
 CC=@CC@
+CC_FOR_BUILD=@CC_FOR_BUILD@
 RM=@RM@
 AWK=@AWK@
 SHELL=@SHELL@

Added: apr/apr/trunk/build/ax_prog_cc_for_build.m4
URL: http://svn.apache.org/viewvc/apr/apr/trunk/build/ax_prog_cc_for_build.m4?rev=1871998&view=auto
 ==============================================================================
--- apr/apr/trunk/build/ax_prog_cc_for_build.m4 (added)
+++ apr/apr/trunk/build/ax_prog_cc_for_build.m4 Thu Dec 26 11:04:58 2019
@@ -0,0 +1,126 @@
+# ===========================================================================
+#   https://www.gnu.org/software/autoconf-archive/ax_prog_cc_for_build.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_PROG_CC_FOR_BUILD
+#
+# DESCRIPTION
+#
+#   This macro searches for a C compiler that generates native executables,
+#   that is a C compiler that surely is not a cross-compiler. This can be
+#   useful if you have to generate source code at compile-time like for
+#   example GCC does.
+#
+#   The macro sets the CC_FOR_BUILD and CPP_FOR_BUILD macros to anything
+#   needed to compile or link (CC_FOR_BUILD) and preprocess (CPP_FOR_BUILD).
+#   The value of these variables can be overridden by the user by specifying
+#   a compiler with an environment variable (like you do for standard CC).
+#
+#   It also sets BUILD_EXEEXT and BUILD_OBJEXT to the executable and object
+#   file extensions for the build platform, and GCC_FOR_BUILD to `yes' if
+#   the compiler we found is GCC. All these variables but GCC_FOR_BUILD are
+#   substituted in the Makefile.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Paolo Bonzini <bonzini@gnu.org>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 9
+
+AU_ALIAS([AC_PROG_CC_FOR_BUILD], [AX_PROG_CC_FOR_BUILD])
+AC_DEFUN([AX_PROG_CC_FOR_BUILD], [dnl
+AC_REQUIRE([AC_PROG_CC])dnl
+AC_REQUIRE([AC_PROG_CPP])dnl
+AC_REQUIRE([AC_EXEEXT])dnl
+AC_REQUIRE([AC_CANONICAL_HOST])dnl
+
+dnl Use the standard macros, but make them use other variable names
+dnl
+pushdef([ac_cv_prog_CPP], ac_cv_build_prog_CPP)dnl
+pushdef([ac_cv_prog_gcc], ac_cv_build_prog_gcc)dnl
+pushdef([ac_cv_prog_cc_works], ac_cv_build_prog_cc_works)dnl
+pushdef([ac_cv_prog_cc_cross], ac_cv_build_prog_cc_cross)dnl
+pushdef([ac_cv_prog_cc_g], ac_cv_build_prog_cc_g)dnl
+pushdef([ac_cv_exeext], ac_cv_build_exeext)dnl
+pushdef([ac_cv_objext], ac_cv_build_objext)dnl
+pushdef([ac_exeext], ac_build_exeext)dnl
+pushdef([ac_objext], ac_build_objext)dnl
+pushdef([CC], CC_FOR_BUILD)dnl
+pushdef([CPP], CPP_FOR_BUILD)dnl
+pushdef([CFLAGS], CFLAGS_FOR_BUILD)dnl
+pushdef([CPPFLAGS], CPPFLAGS_FOR_BUILD)dnl
+pushdef([LDFLAGS], LDFLAGS_FOR_BUILD)dnl
+pushdef([host], build)dnl
+pushdef([host_alias], build_alias)dnl
+pushdef([host_cpu], build_cpu)dnl
+pushdef([host_vendor], build_vendor)dnl
+pushdef([host_os], build_os)dnl
+pushdef([ac_cv_host], ac_cv_build)dnl
+pushdef([ac_cv_host_alias], ac_cv_build_alias)dnl
+pushdef([ac_cv_host_cpu], ac_cv_build_cpu)dnl
+pushdef([ac_cv_host_vendor], ac_cv_build_vendor)dnl
+pushdef([ac_cv_host_os], ac_cv_build_os)dnl
+pushdef([ac_cpp], ac_build_cpp)dnl
+pushdef([ac_compile], ac_build_compile)dnl
+pushdef([ac_link], ac_build_link)dnl
+
+save_cross_compiling=$cross_compiling
+save_ac_tool_prefix=$ac_tool_prefix
+cross_compiling=no
+ac_tool_prefix=
+
+AC_PROG_CC
+AC_PROG_CPP
+AC_EXEEXT
+
+ac_tool_prefix=$save_ac_tool_prefix
+cross_compiling=$save_cross_compiling
+
+dnl Restore the old definitions
+dnl
+popdef([ac_link])dnl
+popdef([ac_compile])dnl
+popdef([ac_cpp])dnl
+popdef([ac_cv_host_os])dnl
+popdef([ac_cv_host_vendor])dnl
+popdef([ac_cv_host_cpu])dnl
+popdef([ac_cv_host_alias])dnl
+popdef([ac_cv_host])dnl
+popdef([host_os])dnl
+popdef([host_vendor])dnl
+popdef([host_cpu])dnl
+popdef([host_alias])dnl
+popdef([host])dnl
+popdef([LDFLAGS])dnl
+popdef([CPPFLAGS])dnl
+popdef([CFLAGS])dnl
+popdef([CPP])dnl
+popdef([CC])dnl
+popdef([ac_objext])dnl
+popdef([ac_exeext])dnl
+popdef([ac_cv_objext])dnl
+popdef([ac_cv_exeext])dnl
+popdef([ac_cv_prog_cc_g])dnl
+popdef([ac_cv_prog_cc_cross])dnl
+popdef([ac_cv_prog_cc_works])dnl
+popdef([ac_cv_prog_gcc])dnl
+popdef([ac_cv_prog_CPP])dnl
+
+dnl Finally, set Makefile variables
+dnl
+BUILD_EXEEXT=$ac_build_exeext
+BUILD_OBJEXT=$ac_build_objext
+AC_SUBST(BUILD_EXEEXT)dnl
+AC_SUBST(BUILD_OBJEXT)dnl
+AC_SUBST([CFLAGS_FOR_BUILD])dnl
+AC_SUBST([CPPFLAGS_FOR_BUILD])dnl
+AC_SUBST([LDFLAGS_FOR_BUILD])dnl
+])
+

Modified: apr/apr/trunk/build/buildcheck.sh
URL: http://svn.apache.org/viewvc/apr/apr/trunk/build/buildcheck.sh?rev=1871998&r1=1871997&r2=1871998&view=diff
 ==============================================================================
--- apr/apr/trunk/build/buildcheck.sh (original)
+++ apr/apr/trunk/build/buildcheck.sh Thu Dec 26 11:04:58 2019
@@ -40,7 +40,9 @@ fi
 # output is multiline from 1.5 onwards
 
 # Require libtool 1.4 or newer
-libtool=`build/PrintPath glibtool1 glibtool libtool libtool15 libtool14`
+if test -z "$libtool"; then
+  libtool=`build/PrintPath glibtool1 glibtool libtool libtool15 libtool14`
+fi
 lt_pversion=`$libtool --version 2>/dev/null|sed -e 's/([^)]*)//g;s/^[^0-9]*//;s/[- \
].*//g;q'`  if test -z "$lt_pversion"; then
   echo "buildconf: libtool not found."

Modified: apr/apr/trunk/configure.in
URL: http://svn.apache.org/viewvc/apr/apr/trunk/configure.in?rev=1871998&r1=1871997&r2=1871998&view=diff
 ==============================================================================
--- apr/apr/trunk/configure.in (original)
+++ apr/apr/trunk/configure.in Thu Dec 26 11:04:58 2019
@@ -35,6 +35,8 @@ sinclude(build/dbd.m4)
 sinclude(build/dso.m4)
 sinclude(build/iconv.m4)
 
+sinclude(build/ax_prog_cc_for_build.m4)
+
 dnl Hard-coded top of apr_private.h:
 AH_TOP([
 #ifndef APR_PRIVATE_H
@@ -196,6 +198,9 @@ dnl can only be used once within a confi
 dnl preload section from invoking the macro to get compiler info.
 AC_PROG_CC
 
+dnl Check build CC for gen_test_char compiling which is executed at build time.
+AX_PROG_CC_FOR_BUILD
+
 dnl AC_PROG_SED is only avaliable in recent autoconf versions.
 dnl Use AC_CHECK_PROG instead if AC_PROG_SED is not present.
 ifdef([AC_PROG_SED],


[prev in list] [next in list] [prev in thread] [next in thread]
Configure | About | News | Add a list | Sponsored by KoreLogic